用前导零填充字符串，使其在 SQL Server 2008 中的长度为 3 个字符

如果该字段已经是一个字符串，这将起作用

 SELECT RIGHT('000'+ISNULL(field,''),3)

如果您希望空值显示为“000”

它可能是一个整数——那么你会想要

 SELECT RIGHT('000'+CAST(field AS VARCHAR(3)),3)

根据问题的要求，此答案仅在长度 <= 3 时才有效，如果您想要更大的东西，则需要将字符串常量和两个整数常量更改为所需的宽度。例如 '0000' 和 VARCHAR(4)),4

---

虽然问题是针对 SQL Server 2008 R2，但如果有人正在使用 2012 及更高版本阅读此内容，那么使用 FORMAT 会变得更加容易。

您可以传递 standard numeric format string 或 custom numeric format string 作为格式参数（感谢 Vadim Ovchinnikov 的提示）。

对于这个问题，例如像这样的代码

DECLARE @myInt INT = 1;
-- One way using a standard numeric format string
PRINT FORMAT(@myInt,'D3');
-- Other way using a custom numeric format string
PRINT FORMAT(@myInt,'00#');

输出

001
001

---

安全的方法：

SELECT REPLACE(STR(n,3),' ','0')

这样做的好处是返回字符串 '***' for n < 0 或 n > 999，这是一个很好且明显的越界输入指标。此处列出的其他方法将通过将输入截断为 3 个字符的子字符串来静默失败。

---

这是我在 SQL Server Express 2012 中使用的 Hogan 答案的变体：

SELECT RIGHT(CONCAT('000', field), 3)

我不必担心该字段是否为字符串，而只需 CONCAT 它，因为它无论如何都会输出字符串。此外，如果该字段可以是 NULL，则可能需要使用 ISNULL 以避免函数获得 NULL 结果。

SELECT RIGHT(CONCAT('000', ISNULL(field,'')), 3)

---

这是一种更通用的技术，用于向左填充到任何所需的宽度：

declare @x     int     = 123 -- value to be padded
declare @width int     = 25  -- desired width
declare @pad   char(1) = '0' -- pad character

select right_justified = replicate(
                           @pad ,
                           @width-len(convert(varchar(100),@x))
                           )
                       + convert(varchar(100),@x)

但是，如果您正在处理负值并使用前导零填充，则此方法或其他建议的技术都不起作用。你会得到如下所示的东西：

00-123

[可能不是你想要的]

所以......你将不得不跳过一些额外的障碍这是一种可以正确格式化负数的方法：

declare @x     float   = -1.234
declare @width int     = 20
declare @pad   char(1) = '0'

select right_justified = stuff(
         convert(varchar(99),@x) ,                            -- source string (converted from numeric value)
         case when @x < 0 then 2 else 1 end ,                 -- insert position
         0 ,                                                  -- count of characters to remove from source string
         replicate(@pad,@width-len(convert(varchar(99),@x)) ) -- text to be inserted
         )

应该注意的是，convert() 调用应该指定一个足够长的 [n]varchar 来保存带有截断的转换结果。

---

我一直发现以下方法非常有帮助。

REPLICATE('0', 5 - LEN(Job.Number)) + CAST(Job.Number AS varchar) as 'NumberFull'

---

使用适合各种情况的此功能。

CREATE FUNCTION dbo.fnNumPadLeft (@input INT, @pad tinyint)
RETURNS VARCHAR(250)
AS BEGIN
    DECLARE @NumStr VARCHAR(250)

    SET @NumStr = LTRIM(@input)

    IF(@pad > LEN(@NumStr))
        SET @NumStr = REPLICATE('0', @Pad - LEN(@NumStr)) + @NumStr;

    RETURN @NumStr;
END

样本输出

SELECT [dbo].[fnNumPadLeft] (2016,10) -- returns 0000002016
SELECT [dbo].[fnNumPadLeft] (2016,5) -- returns 02016
SELECT [dbo].[fnNumPadLeft] (2016,2) -- returns 2016
SELECT [dbo].[fnNumPadLeft] (2016,0) -- returns 2016 

---

对于那些想要更新他们现有数据的人来说，这里是查询：

update SomeEventTable set eventTime=RIGHT('00000'+ISNULL(eventTime, ''),5)

---

我知道这是一张旧票，但我只是想分享一下：

我发现这段代码提供了一个解决方案。不确定它是否适用于所有版本的 MSSQL；我有 MSSQL 2016。

declare @value as nvarchar(50) = 23
select REPLACE(STR(CAST(@value AS INT) + 1,4), SPACE(1), '0') as Leadingzero

这将返回“0023”。

STR函数中的4是总长度，包括数值。例如，4、23 和 123 在 STR 中都将有 4，并且将添加正确数量的零。您可以增加或减少它。无需获取 23 的长度。

编辑：我看到它与@Anon 的帖子相同。

---

对于整数，您可以使用从 int 到 varchar 的隐式转换：

SELECT RIGHT(1000 + field, 3)

---

用固定长度试试这个。

select right('000000'+'123',5)

select REPLICATE('0', 5 - LEN(123)) + '123'

---

当我需要固定大小的 varchar（或字符串）输出时，我在整数列作为输入时遇到了类似的问题。例如，1 到“01”，12 到“12”。此代码有效：

SELECT RIGHT(CONCAT('00',field::text),2)

如果输入也是一列varchar，则可以避免强制转换部分。

---

对于更动态的方法，试试这个。

declare @val varchar(5)
declare @maxSpaces int
set @maxSpaces = 3
set @val = '3'
select concat(REPLICATE('0',@maxSpaces-len(@val)),@val)

---

写这个是因为我有一个特定长度的要求（9）。仅当输入需要填充时，才使用 @pattern 填充左侧。应始终返回在@pattern 中定义的长度。

declare @charInput as char(50) = 'input'

--always handle NULL :)
set @charInput = isnull(@charInput,'')

declare @actualLength as int = len(@charInput)

declare @pattern as char(50) = '123456789'
declare @prefLength as int = len(@pattern)

if @prefLength > @actualLength
    select Left(Left(@pattern, @prefLength-@actualLength) + @charInput, @prefLength)
else
    select @charInput

返回 1234 输入

---

简单就是这样

喜欢：

DECLARE @DUENO BIGINT
SET @DUENO=5

SELECT 'ND'+STUFF('000000',6-LEN(RTRIM(@DueNo))+1,LEN(RTRIM(@DueNo)),RTRIM(@DueNo)) DUENO

---

最后我决定使用这个：

RIGHT(STUFF(ReceiptNum, 1, 0, replicate('0',10)),10)

---

我专门来这里研究如何将我的 timezoneoffset 转换为 timezone 字符串，以便在 SQL Server 2008 中将日期转换为 DATETIMEOFFSET。Gross，但必要。

所以我需要一种方法来处理负数和正数，如果需要，将它们格式化为两个带有前导零的字符。 Anons answer 让我很接近，但负时区值会显示为 0-5 而不是必需的 -05

因此，对他的答案进行一些调整，这适用于所有时区小时转换

DECLARE @n INT = 13 -- Works with -13, -5, 0, 5, etc
SELECT CASE 
    WHEN @n < 0 THEN '-' + REPLACE(STR(@n * -1 ,2),' ','0') 
    ELSE '+' + REPLACE(STR(@n,2),' ','0') END + ':00'

---

我创建了这个函数，它适用于 bigint 和一个前导零或其他单个字符（最多返回 20 个字符），并允许结果长度小于输入数字的长度：

create FUNCTION fnPadNum (
  @Num BIGINT --Number to be padded, @sLen BIGINT --Total length of results , @PadChar varchar(1))
  RETURNS VARCHAR(20)
  AS
  --Pads bigint with leading 0's
            --Sample:  "select dbo.fnPadNum(201,5,'0')" returns "00201"
            --Sample:  "select dbo.fnPadNum(201,5,'*')" returns "**201"
            --Sample:  "select dbo.fnPadNum(201,5,' ')" returns "  201"
   BEGIN
     DECLARE @Results VARCHAR(20)
     SELECT @Results = CASE 
     WHEN @sLen >= len(ISNULL(@Num, 0))
     THEN replicate(@PadChar, @sLen - len(@Num)) + CAST(ISNULL(@Num, 0) AS VARCHAR)
     ELSE CAST(ISNULL(@Num, 0) AS VARCHAR)
     END

     RETURN @Results
     END
     GO

     --Usage:
      SELECT dbo.fnPadNum(201, 5,'0')
      SELECT dbo.fnPadNum(201, 5,'*')
      SELECT dbo.fnPadNum(201, 5,' ')

---