如果...或如果...在 Windows 批处理文件中

zmbq 解决方案很好，但不能在所有情况下都使用，例如在 FOR DO(...) 循环之类的代码块中。

另一种方法是使用指示变量。将其初始化为未定义，然后仅当任何一个 OR 条件为真时才定义它。然后使用 IF DEFINED 作为最终测试 - 无需使用延迟扩展。

FOR ..... DO (
  set "TRUE="
  IF cond1 set TRUE=1
  IF cond2 set TRUE=1
  IF defined TRUE (
    ...
  ) else (
    ...
  )
)

您可以添加 arasmussen 使用的 ELSE IF 逻辑，因为如果第一个条件为真，它的执行速度可能会快一点，但我从不打扰。

附录 - 这是一个重复的问题，对 Using an OR in an IF statement WinXP Batch Script 的答案几乎相同

最后的附录 - 我几乎忘记了我最喜欢的测试变量是否是不区分大小写值列表中的任何一个的技术。初始化一个包含可接受值的分隔列表的测试变量，然后使用搜索和替换来测试您的变量是否在列表中。这非常快，并且对任意长的列表使用最少的代码。它确实需要延迟扩展（或者 CALL %%VAR%% 技巧）。此外，该测试不区分大小写。

set "TEST=;val1;val2;val3;val4;val5;"
if "!TEST:;%VAR%;=!" neq "!TEST!" (echo true) else (echo false)

如果 VAR 包含 =，上述可能会失败，因此测试不是万无一失的。

如果在需要延迟扩展以访问 VAR 的当前值的块内进行测试，则

for ... do (
  set "TEST=;val1;val2;val3;val4;val5;"
  for /f %%A in (";!VAR!;") do if "!TEST:%%A=!" neq "!TEST!" (echo true) else (echo false)
)

根据 VAR 中的预期值，可能需要诸如“delims=”之类的选项

通过添加更多代码，即使在 VAR 中使用 =，上述策略也可以变得可靠。

set "TEST=;val1;val2;val3;val4;val5;"
if "!TEST:;%VAR%;=!" neq "!TEST!" if "!TEST:;%VAR%;=;%VAR%;"=="!TEST!" echo true

但是现在我们已经失去了提供 ELSE 子句的能力，除非我们添加一个指示变量。代码开始看起来有点“难看”，但我认为它是测试 VAR 是否是任意数量的不区分大小写选项中的任何一个的性能最好的可靠方法。

最后还有一个更简单的版本，我认为它稍微慢一些，因为它必须为每个值执行一个 IF。 Aacini 在对前面提到的链接中接受的答案的评论中提供了这个解决方案

for %%A in ("val1" "val2" "val3" "val4" "val5") do if "%VAR%"==%%A echo true

值列表不能包含 * 或 ?字符，并且值和 %VAR% 不应包含引号。如果 %VAR% 还包含空格或特殊字符（如 ^、& 等），则引号会导致问题。此解决方案的另一个限制是它不提供 ELSE 子句选项，除非您添加指示变量。优点是它可以区分大小写或不区分大小写，具体取决于是否存在 IF /I 选项。

---

我不这么认为。只需使用两个 IF 和 GOTO 相同的标签：

IF cond1 GOTO foundit
IF cond2 GOTO foundit

ECHO Didn't found it
GOTO end

:foundit
ECHO Found it!

:end

---

可以在单行中使用简单的“FOR”来使用“或”条件：

FOR %%a in (item1 item2 ...) DO IF {condition_involving_%%a} {execute_command}  

适用于您的案例：

FOR %%a in (1 2) DO IF %var%==%%a ECHO TRUE

禁止执行两次

有评论指出 {execute_command} 可能会遇到两次。为避免这种情况，您可以在第一次遇到后使用 goto。

FOR %%a in (1 2) DO IF %var%==%%a (
    ECHO TRUE
    goto :continue
)
:continue 

如果您认为 {execute_command} 可能会被执行两次而您不希望这样，您可以添加 && goto :eof：

FOR %%a in (1 2) DO IF %var%==%%a ECHO TRUE && goto :eof

简单得多，而且仍然在一条线上。

---

感谢这篇文章，它对我帮助很大。

不知道它是否可以提供帮助，但我遇到了问题，多亏了你，我发现我认为是另一种基于布尔等价来解决它的方法：

“A or B”与“not(not A and not B)”相同

因此：

IF [%var%] == [1] OR IF [%var%] == [2] ECHO TRUE

变成：

IF not [%var%] == [1] IF not [%var%] == [2] ECHO FALSE

---

即使这个问题有点老：

如果你想使用 if cond1 or cond 2 - 你不应该使用复杂的循环或类似的东西。

简单地提供两个 ifs 彼此结合 goto - 这是一个隐含的或。

//thats an implicit IF cond1 OR cond2 OR cond3
if cond1 GOTO doit
if cond2 GOTO doit
if cond3 GOTO doit

//thats our else.
GOTO end

:doit
  echo "doing it"

:end

如果没有 goto 而是“就地”操作，如果所有条件都匹配，您可能会执行该操作 3 次。

---

Batch 中没有 IF <arg> OR 或 ELIF 或 ELSE IF，但是...

尝试将其他 IF 嵌套在前一个 IF 的 ELSE 中。

IF <arg> (
    ....
) ELSE (
    IF <arg> (
        ......
    ) ELSE (
        IF <arg> (
            ....
        ) ELSE (
    )
)

---

可以使用一个函数来评估 OR 逻辑并返回一个值。

@echo off
set var1=3
set var2=5
call :logic_or orResult "'%var1%'=='4'" "'%var2%'=='5'"
if %orResult%==1 ( 
    echo At least one expression is true
) ELSE echo All expressions are false
exit /b

:logic_or <resultVar> expression1 [[expr2] ... expr-n] 
SETLOCAL
set "logic_or.result=0"
set "logic_or.resultVar=%~1"

:logic_or_loop 
if "%~2"=="" goto :logic_or_end 
if %~2 set "logic_or.result=1"
SHIFT 
goto :logic_or_loop 

:logic_or_end 
( 
  ENDLOCAL 
  set "%logic_or.resultVar%=%logic_or.result%"
  exit /b
) 

---

该目标可以通过间接使用 IF 来实现。

下面是一个复杂表达式的示例，可以在 CMD 批处理中非常简洁和合乎逻辑地编写，没有不连贯的标签和 GOTO。

() 括号之间的代码块由 CMD 处理为一种（可怜的）子外壳。无论从块中出来的退出代码都将用于确定块在更大的布尔表达式中播放的真/假值。使用这些代码块可以构建任意大的布尔表达式。

简单的例子

每个块被解析为真（即在块中的最后一条语句执行后 ERRORLEVEL = 0）/假，直到整个表达式的值被确定或控制跳出（例如通过 GOTO）：

 ((DIR c:\xsgdde /w) || (DIR c:\ /w)) && (ECHO -=BINGO=-)

复杂的例子

这解决了最初提出的问题。每个块中可以有多个语句，但在 || || ||表达式最好简洁明了，以便尽可能易读。 ^ 是 CMD 批处理中的转义字符，当放置在行尾时，它将转义 EOL 并指示 CMD 继续读取下一行的当前批处理语句。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

(
    (CALL :ProcedureType1 a b) ^
        || (CALL :ProcedureType2 sgd) ^
            || (CALL :ProcedureType1 c c)
) ^
    && (
        ECHO -=BINGO=-
        GOTO :EOF
    )
ECHO -=no bingo for you=-
GOTO :EOF

:ProcedureType1
    IF "%~1" == "%~2" (EXIT /B 0) ELSE (EXIT /B 1)
GOTO :EOF (this line is decorative as it's never reached)

:ProcedureType2
    ECHO :ax:xa:xx:aa:|FINDSTR /I /L /C:":%~1:">nul
GOTO :EOF

---

If %x%==1 (
If %y%==1 (
:: both are equal to 1.
)
)

那是为了检查多个变量是否相等。这是任何一个变量。

If %x%==1 (
:: true
)
If %x%==0 (
If %y%==1 (
:: true
)
)
If %x%==0 (
If %y%==0 (
:: False
)
)

如果我的头，我只是想到了这一点。我可以更压缩它。

---

我意识到这个问题很老，但我想发布一个替代解决方案，以防其他人（比如我自己）在遇到同样问题时发现这个线程。通过回显变量并使用 findstr 进行验证，我能够解决缺少 OR 运算符的问题。

for /f %%v in ('echo %var% ^| findstr /x /c:"1" /c:"2"') do (
    if %errorlevel% equ 0 echo true
)

---

虽然 dbenham 的答案非常好，但如果您要检查的变量不是 environment 变量，则依赖 IF DEFINED 会给您带来很多麻烦。脚本变量没有得到这种特殊处理。

虽然这看起来像是一些可笑的无证 BS，但使用 IF /? 对 IF 进行简单的 shell 查询会发现，

DEFINED 条件的工作方式与 EXIST 类似，只是它采用环境变量名称，如果定义了环境变量，则返回 true。

关于回答这个问题，是否有理由在一系列评估后不只使用一个简单的标志？就底层逻辑和可读性而言，这对我来说似乎是最灵活的 OR 检查。例如：

Set Evaluated_True=false

IF %condition_1%==true (Set Evaluated_True=true)
IF %some_string%=="desired result" (Set Evaluated_True=true)
IF %set_numerical_variable% EQ %desired_numerical_value% (Set Evaluated_True=true)

IF %Evaluated_True%==true (echo This is where you do your passing logic) ELSE (echo This is where you do your failing logic)

显然，它们可以是任何类型的条件评估，但我只是分享几个例子。

如果您想将所有内容按书面形式放在一行上，则可以将它们与 && 链接在一起，例如：

Set Evaluated_True=false

IF %condition_1%==true (Set Evaluated_True=true) && IF %some_string%=="desired result" (Set Evaluated_True=true) && IF %set_numerical_variable% EQ %desired_numerical_value% (Set Evaluated_True=true)

IF %Evaluated_True%==true (echo This is where you do your passing logic) ELSE (echo This is where you do your failing logic)

---

从来没有存在过工作。

如果不存在，我使用 g:xyz/what goto h: Else xcopy c:current/files g:bu/current 有修饰符 /a 等。不确定是哪些。店里的笔记本电脑。和办公室里的电脑。我不在那里。

从来没有让批处理文件在 Windows XP 上运行

---

我通常使用的一个更快的替代方案如下，因为我可以“或”可以适应可变空间的任意数量的条件

@(
  Echo off
  Set "_Match= 1 2 3 "
)

Set /a "var=3"

Echo:%_Match%|Find " %var% ">nul || (
  REM Code for a false condition goes here
) && (
  REM code for a true condition goes here.
)

---

这很简单，只需在下面使用

IF %var% == 1 (
ECHO TRUE)

IF %var% == 2 (
ECHO TRUE)

---

另一种选择是显示当前环境变量并利用 FINDSTR 的默认行为：

FINDSTR "hello there" xy 在文件 xy 中搜索 "hello" 或 "there"

所以

SET | FINDSTR /I /X "var=1 var=2" >NUL
IF %ERRORLEVEL% EQU 0 (
    ECHO TRUE
) ELSE (
    ECHO FALSE
)

在哪里

/I 指定搜索不区分大小写。 /X 打印完全匹配的行。

如果首选正则表达式，请改用 FINDSTR /R /I "^var=1$ ^var=2$" >NUL。

编辑：如果变量字符串包含空格，则应使用FINDSTR /R，例如FINDSTR /R /I "^var=1 a$ ^var=2 b$" >NUL。

编辑：如果变量字符串包含空格，则应使用文字搜索字符串。例如，FINDSTR /I /X /C:"var=1 a" /C:"var=2 b" >NUL。

---

只需将 SET 更改为 SET var，或者最好更改为 (SET var) 2>NUL，您就可以使这个答案更有效。要执行问题中所示的任务，作为单行程序，您只需使用条件执行，即(Set var) 2>NUL | %SystemRoot%\System32\findstr.exe /B /E /I "var=1 var=2" 1>NUL && Echo TRUE。

@Compo 使用不带参数的 SET 允许使用不同的变量，例如 my_test_var 和 your_test_var。

您的变量和 OP 的变量被专门命名为 var。在这种情况下列出每个变量是绝对没有必要的。因此效率低下。至少使用 var 只会返回名称以这三个字符开头的那些！