ChatGPT解决这个技术问题 Extra ChatGPT

Globally override key binding in Emacs

How can I set a key binding that globally overrides and takes precedence over all other bindings for that key? I want to override all major/minor mode maps and make sure my binding is always in effect.

This of course doesn't work:

(global-set-key "\C-i" 'some-function)

It works in text-mode, but when I use lisp-mode, C-i is rebound to lisp-indent-line.

I can go through and override this binding in lisp-mode and in every other mode individually, but there must be an easier way. Every time I install a new mode for a new file type, I'd have to go back and check to make sure that all of my key bindings aren't being overridden by the new mode.

I want to do this because I want to emulate bindings I've already learned and ingrained from other editors.

Cross-referencing with subsequent duplicate at emacs.stackexchange.com/questions/352/…

S
Stefan

I use a minor mode for all my "override" key bindings:

(defvar my-keys-minor-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "C-i") 'some-function)
    map)
  "my-keys-minor-mode keymap.")

(define-minor-mode my-keys-minor-mode
  "A minor mode so that my key settings override annoying major modes."
  :init-value t
  :lighter " my-keys")

(my-keys-minor-mode 1)

This has the added benefit of being able to turn off all my modifications in one fell swoop (just disable the minor mode) in case someone else is driving the keyboard or if I need to see what a default key binding does.

Note that you may need to turn this off in the minibuffer:

(defun my-minibuffer-setup-hook ()
  (my-keys-minor-mode 0))

(add-hook 'minibuffer-setup-hook 'my-minibuffer-setup-hook)

This seems like a good idea. Is there any way to make sure your minor mode doesn't fight with other minor modes?
Make sure your minor mode is first on the list minor-mode-map-alist.
Trey is right. Usually putting this near the end of your .emacs is enough. Also, most bindings you'd override would be ones that major modes are setting ... minor modes generally stay out of the way.
I followed this approach, but then I realized that anything I bind to C-i also gets bound to the TAB key. Any suggestions?
Brian Carper: Here's an enhancement to deal with subsequently-loaded minor modes: stackoverflow.com/questions/683425/…
C
Community

As an addition to scottfrazer's answer, I've written the following so that my keybindings retain precedence, even if subsequently-loaded libraries bring in new keymaps of their own.

Because keymaps can be generated at compile time, load seemed like the best place to do this.

(add-hook 'after-load-functions 'my-keys-have-priority)

(defun my-keys-have-priority (_file)
  "Try to ensure that my keybindings retain priority over other minor modes.

Called via the `after-load-functions' special hook."
  (unless (eq (caar minor-mode-map-alist) 'my-keys-minor-mode)
    (let ((mykeys (assq 'my-keys-minor-mode minor-mode-map-alist)))
      (assq-delete-all 'my-keys-minor-mode minor-mode-map-alist)
      (add-to-list 'minor-mode-map-alist mykeys))))

I pasted your script but it didn't make any affect :(
@alper I suggest that you post a question with all of the relevant details, including the code you're actually using, and a specific example/recipe to reproduce the problem.
M
Mirzhan Irkegulov

Install use-package, eval and you're done:

(require 'bind-key)
(bind-key* "C-i" 'some-function)

Install only bind-key is enough for the use case, though use-package depends on bind-key.
This ('bind-key' package) seems to be the most convenient solution; thanks for sharing.
is it disabled on the minibuffer-setup-hook ?
t
tshepang

I found this question while searching for "emacs undefine org mode keybindings", because I wanted to unbind the existing C-c C-b behavior to allow my global map to bury-buffer to work in an org buffer.

This ended up being the simplest solution for me:

(add-hook 'org-mode-hook
      (lambda ()
        (local-unset-key (kbd "C-c C-b"))))

This is mode-specific and doesn't address the bigger picture even though it does work for your single use case.
K
Kirkland

Although scottfrazer's answer is exactly what you asked for, I will mention for posterity another solution.

From The Emacs Manual:

"Don't define C-c letter as a key in Lisp programs. Sequences consisting of C-c and a letter (either upper or lower case) are reserved for users; they are the only sequences reserved for users, so do not block them."

If you bind your personal global bindings to C-c plus a letter, then you "should" be safe. However, this is merely a convention, and any mode is still able to override your bindings.


I didn't expect org-mode, of all modes, to break this rule. `C-c C-h' tells me that C-c a, b, c, and l are bound to org-agenda, org-iswitchb, org-capture, and org-store-link, respectively.
Afaik, binding these is the first step org-mode suggests in order to use it, but the user has to define them himself (i.e. it's not done by default), and may choose any other while doing so. (also, it's because these bindings are supposed to be global, not bound to the org major mode)
C
Community

If you want to "always use the keybinds in the map, unless I explicitly override them for a specific mode-map", and assuming you are using scottfrazier's approach, you want:

(defun locally-override (key cmd)
  (unless (local-variable-p 'my-keys-minor-mode-map)
    (set (make-variable-buffer-local 'my-keys-minor-mode-map)
         (make-sparse-keymap))
    (set-keymap-parent my-keys-minor-mode-map 
                       (default-value 'my-keys-minor-mode-map)))
  (define-key my-keys-minor-mode-map key cmd))

So

(locally-override "\C-i" nil)

should remove the "\C-i" binding from the minor mode in the current buffer only. Warning: this is completely untested, but seems like the right approach. The point of setting the parent rather than just coping the global value of my-keys-minor-mode-map is so any later changes to the global value are automatically reflected in the local value.


T
T.E.D.

I don't think you can. That is roughly equivalent to saying that you want to define a global variable that cannot be hidden by local variable declarations in functions. Scope just doesn't work that way.

However, there might be a way to write an elisp function to go through the mode list and reassign it in every single one for you.


This idea of scoping is technically correct, but overriding-local-map is specifically designed to override all other maps. However it's dangerous to use it.
J
JesperE

Unless you really want to do this yourself, you should check around and see if anyone else already has done it.

There is a package for Emacs which gives your windows-like keybindings. You should be able to find it through google.


The package you are thinking of is probably cua-mode.
Yes, that's the package.
c
c4710n

In Emacs 27, there's override-global-map. Then, you can do something like this: (define-key override-global-map (kbd "M-h") 'backward-kill-word)

This answer is not right, sorry.


Where is that keymap defined?
Sorry for that, this keymap is defined by bind-key package which is not included in Emacs. I will claim it in my post.