如何将参数传递给批处理文件？

另一个有用的提示是使用 %* 表示“全部”。例如：

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

当你运行时：

test-command admin password foo bar

上面的批处理文件将运行：

fake-command /u admin /p password admin password foo bar

我的语法可能略有错误，但这是一般的想法。

---

我是这样做的：

@fake-command /u %1 /p %2

该命令如下所示：

test.cmd admin P@55w0rd > test-log.txt

%1 适用于第一个参数，%2（这是棘手的部分）适用于第二个参数。您最多可以有 9 个以这种方式传递的参数。

---

如果您想智能地处理丢失的参数，您可以执行以下操作：

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

---

使用 %1、%2、... %9 或 %* 可以很简单地访问批处理参数，但前提是内容很简单。

对于像 "&"^& 这样的复杂内容没有简单的方法，因为不可能访问 %1 而不会产生错误。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

线条扩展为

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

并且每一行都失败了，因为其中一个 & 在引号之外。

它可以通过从临时文件中读取参数的注释版本来解决。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

诀窍是启用 echo on 并在 rem 语句之后展开 %1（也适用于 %2 .. %*）。
因此，即使 "&"& 也可以回显而不会产生错误，正如它所指出的那样。

但是为了能够重定向 echo on 的输出，您需要两个 for 循环。

额外的字符 * # 用于保护 /? 之类的内容（将显示 REM 的帮助）。
或者行尾的插入符号 ^ 可以用作多行字符，即使在rem。

然后从文件中读取 rem 参数 输出，但要小心。
FOR /F 应该在延迟扩展关闭的情况下工作，否则内容带有“！”将被销毁。
删除 param1 中的多余字符后，您明白了。

并以安全的方式使用 param1，启用延迟扩展。

---

是的，只是不要忘记在使用 if 和 for 和帮派时使用像 %%1 这样的变量。

如果您忘记了双 %，那么您将替换为（可能为 null）命令行参数，并且您将收到一些非常混乱的错误消息。

---

没有必要让它复杂化。它只是命令 %1 %2 参数，例如，

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

“暂停”显示批处理文件已完成的操作并等待您按 ANY 键。在 Windows 文件夹中将其另存为 xx.bat。

要使用它，请键入，例如：

xx c:\f\30\*.* f:\sites\30

这个批处理文件负责所有必要的参数，比如只复制文件、更新的文件等。我在 Windows 之前就使用过它。如果您喜欢在复制文件时查看文件的名称，请忽略 Q 参数。

---

最近有朋友问我这个问题，所以我想我会发布我如何处理批处理文件中的命令行参数。

正如您将看到的那样，这种技术有一些开销，但它使我的批处理文件非常容易理解并且可以快速实现。以及支持以下结构：

>template.bat [-f] [--flag] [--namedvalue value] arg1 [arg2][arg3][...]

它的要点是具有 :init、:parse 和 :main 函数。

示例用法

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

模板.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse
    if /i "%~1"=="-f"         set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

---

在批处理文件中

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

%1 和 %2 分别返回第一个和第二个参数值。

在命令行中，传递参数

Directory> batchFileName admin P@55w0rd 

输出将是

admin
P@55w0rd

---

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

注意：如果 %1 本身包含在引号中，IF "%1"=="" 将导致问题。

在这种情况下，请使用 IF [%1]==[]，或者，仅在 NT 4 (SP6) 及更高版本中，使用 IF "%~1"==""。

---

让我们保持简单。

这是 .cmd 文件。

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

这是来自命令行的 3 个调用。

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

---

每个人的回答都非常复杂，但实际上非常简单。 %1 %2 %3 等是解析到文件的参数。 %1 是论证 1，%2 是论证 2，依此类推。

所以，如果我有一个包含以下内容的 bat 脚本：

@echo off
echo %1

当我运行批处理脚本时，我输入：

C:> script.bat Hello

该脚本将简单地输出以下内容：

Hello

这对于脚本中的某些变量非常有用，例如姓名和年龄。所以，如果我有这样的脚本：

@echo off
echo Your name is: %1
echo Your age is: %2

当我输入这个：

C:> script.bat Oliver 1000

我得到这个输出：

Your name is: Oliver
Your age is: 1000

---

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

这会遍历批处理参数 (%*)，无论它们是否被引用，然后回显每个参数。

---

我编写了一个简单的 read_params 脚本，它可以作为函数（或外部 .bat）调用，并将所有变量放入当前环境。它不会修改原始参数，因为call函数使用原始参数的副本进行编辑。

例如，给定以下命令：

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat 将能够在调用函数后使用变量：

call :read_params %*

echo %random%
echo %greeting%

这是功能：

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

限制

无法加载没有值的参数，例如 -force。您可以使用 -force=true 但我想不出一种方法来允许空白值，而无需提前知道没有值的参数列表。

变更日志

2/18/2016 不再需要延迟扩展现在通过查找 - before 参数与其他命令行参数一起使用。

不再需要延迟扩展

现在通过查找 - before 参数来处理其他命令行参数。

---

受@Jon 的 answer elsewhere 启发，我设计了一个更通用的算法来提取命名参数、可选值和开关。

假设我们要实现一个实用程序 foobar。它需要一个初始命令。它有一个可选参数 --foo，它接受一个 optional 值（当然，它不能是另一个参数）；如果缺少该值，则默认为 default。它还有一个可选参数 --bar，它采用 必需 值。最后，它可以带一个标志 --baz，但不允许任何值。哦，这些参数可以按任何顺序出现。

换句话说，它看起来像这样：

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这是一个解决方案：

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

使用 SETLOCAL 使变量不会逃到调用环境中。

不要忘记初始化变量 SET FOO= 等，以防有人在调用环境中定义它们。

使用 %~1 删除引号。

使用 IF "%ARG%" == "" 而不是 IF [%ARG%] == [] 因为 [ 和 ] 根本不会使用以空格结尾的值。

即使您在 IF 块内进行 SHIFT，当前参数（例如 %~1）也不会更新，因为它们是在解析 IF 时确定的。您可以在 IF 块内使用 %~1 和 %~2 ，但这会令人困惑，因为您有一个 SHIFT。为了清楚起见，您可以将 SHIFT 放在块的末尾，但这也可能会丢失和/或混淆人们。因此，在块外“捕获” %~1 和 %~1 似乎是最好的。

您不想使用一个参数代替另一个参数的可选值，因此您必须检查 IF NOT "%ARG:~0,2%" == "--"。

当您使用其中一个参数时，请注意仅 SHIFT。

重复代码 SET FOO=%DEFAULT_FOO% 令人遗憾，但替代方法是在 IF NOT "%ARG%" == "" 块之外添加 IF "%FOO%" == "" SET FOO=%DEFAULT_FOO% .但是，因为它仍然在 IF "%PARAM%" == "--foo" 块内，所以 %FOO% 值会在您进入该块之前进行评估和设置，因此您永远不会检测到 --存在 foo 参数，并且缺少 %FOO% 值。

注意 ECHO Missing bar 的值。 1>&2 将错误消息发送到 stderr。

想要在 Windows 批处理文件中有一个空行？您必须使用 ECHO: 或其中一种变体。

---

要在命令行中引用 set 变量，您需要使用 %a%，例如：

set a=100 
echo %a%  
rem output = 100 

注意：这适用于 Windows 7 专业版。

---

https://i.stack.imgur.com/L2hkd.png

对于使用循环获取所有参数并在纯批处理中：

Obs： 不使用：?*&|<>

@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

您的代码已准备好使用所需的参数编号执行某些操作，例如...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 
 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
 

---

简单的解决方案（即使问题很旧）

测试1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

输出

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

YourLocalPath 是当前目录路径。

为了简单起见，将命令参数存储在变量中并使用变量进行比较。

它不仅写起来简单，而且维护起来也很简单，所以如果以后有人或你在很长一段时间后阅读你的脚本，它就会很容易理解和维护。

编写内联代码：查看其他答案。

---

创建一个新的批处理文件（例如：openclass.bat）并在文件中写入这一行：

java %~n1

然后将批处理文件放在system32文件夹中，转到您的Java类文件，右键单击，属性，打开方式...，然后找到您的批处理文件，选择它，就是这样...

这个对我有用。

PS：我在关闭Java类时找不到关闭cmd窗口的方法。目前...

---

成对的论点

如果您更喜欢在键值对中传递参数，您可以使用如下内容：

@echo off

setlocal enableDelayedExpansion

:::::  asigning arguments as a key-value pairs:::::::::::::
set counter=0
for %%# in (%*) do (    
    set /a counter=counter+1
    set /a even=counter%%2
    
    if !even! == 0 (
        echo setting !prev! to %%#
        set "!prev!=%%~#"
    )
    set "prev=%%~#"
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: showing the assignments
echo %one% %two% %three% %four% %five%

endlocal

还有一个例子：

c:>argumentsDemo.bat one 1 "two" 2 three 3 four 4 "five" 5
1 2 3 4 5

预定义变量

也可以提前设置一些环境变量。可以通过在控制台或 setting them from my computer 中设置它们来完成：

@echo off

if defined variable1 (
    echo %variable1%
)

if defined variable2 (
    echo %variable2%
)

并称它为：

c:\>set variable1=1

c:\>set variable2=2

c:\>argumentsTest.bat
1
2

具有列出值的文件

您还可以指向预设所需值的文件。如果这是脚本：

@echo off

setlocal
::::::::::
set "VALUES_FILE=E:\scripts\values.txt"
:::::::::::


for /f "usebackq eol=: tokens=* delims=" %%# in ("%VALUES_FILE%") do set "%%#"

echo %key1% %key2% %some_other_key%

endlocal

和值文件是这样的：

:::: use EOL=: in the FOR loop to use it as a comment

key1=value1

key2=value2

:::: do not left spaces arround the =
:::: or at the begining of the line

some_other_key=something else

and_one_more=more

调用它的输出将是：

值 1 值 2 别的东西

当然，您可以结合所有方法。还要检查 arguments syntax , shift

---

如果您担心安全/密码盗窃（这导致您设计了这个解决方案，该解决方案在执行时获取登录凭据而不是静态硬编码，而不需要数据库），那么您可以存储 api 或密码解密的一半代码或程序文件中的解密密钥，因此在运行时，如果您正在查看用户在运行时输入凭据，用户将在控制台中键入用户名/密码以进行散列/解密，然后再通过 set /p 传递给程序代码以执行.

如果您正在运行脚本以使用各种用户/密码运行程序，那么命令行参数将适合您。

如果您正在制作一个测试文件以查看不同登录名的输出/效果，那么您可以将所有登录名存储在一个加密文件中，作为 arg 传递给 test.cmd，除非您想坐在命令行并输入所有登录直到完成。

可以提供的参数数量为 limited to total characters on command line。为了克服这个限制，上一段技巧是一种解决方法，不会冒暴露用户密码的风险。

---