如何在 QMake .pro 文件中指定不同的调试/发布输出目录

对于我的 Qt 项目，我在 *.pro 文件中使用了这个方案：

HEADERS += src/dialogs.h
SOURCES += src/main.cpp \
           src/dialogs.cpp

Release:DESTDIR = release
Release:OBJECTS_DIR = release/.obj
Release:MOC_DIR = release/.moc
Release:RCC_DIR = release/.rcc
Release:UI_DIR = release/.ui

Debug:DESTDIR = debug
Debug:OBJECTS_DIR = debug/.obj
Debug:MOC_DIR = debug/.moc
Debug:RCC_DIR = debug/.rcc
Debug:UI_DIR = debug/.ui

这很简单，但很好！ :)

---

要更改目标 dll/exe 的目录，请在您的 pro 文件中使用：

CONFIG(debug, debug|release) {
    DESTDIR = build/debug
} else {
    DESTDIR = build/release
}

您可能还想更改其他构建目标的目录，例如目标文件和 moc 文件（查看 qmake variable reference 了解详细信息或 qmake CONFIG() function reference）。

---

我有一个更紧凑的方法：

release: DESTDIR = build/release
debug:   DESTDIR = build/debug

OBJECTS_DIR = $$DESTDIR/.obj
MOC_DIR = $$DESTDIR/.moc
RCC_DIR = $$DESTDIR/.qrc
UI_DIR = $$DESTDIR/.ui

---

执行此操作的正确方法如下（感谢 QT 支持团队）：

CONFIG(debug, debug|release) {
    DESTDIR = build/debug
}
CONFIG(release, debug|release) {
    DESTDIR = build/release
}

OBJECTS_DIR = $$DESTDIR/.obj
MOC_DIR = $$DESTDIR/.moc
RCC_DIR = $$DESTDIR/.qrc
UI_DIR = $$DESTDIR/.u

更多信息：https://wiki.qt.io/Qt_project_org_faq#What_does_the_syntax_CONFIG.28debug.2Cdebug.7Crelease.29_mean_.3F_What_does_the_1st_argument_specify_and_similarly_what_is_the_2nd_.3F

---

我使用 chalup 建议的相同方法，

ParentDirectory = <your directory>

RCC_DIR = "$$ParentDirectory\Build\RCCFiles"
UI_DIR = "$$ParentDirectory\Build\UICFiles"
MOC_DIR = "$$ParentDirectory\Build\MOCFiles"
OBJECTS_DIR = "$$ParentDirectory\Build\ObjFiles"

CONFIG(debug, debug|release) { 
    DESTDIR = "$$ParentDirectory\debug"
}
CONFIG(release, debug|release) { 
    DESTDIR = "$$ParentDirectory\release"
}

---

老问题，但仍然值得一个最新的答案。今天，当使用影子构建时，通常会执行 Qt Creator 所做的事情（在打开新项目时默认启用它们）。

对于每个不同的构建目标和类型，正确的 qmake 在不同的构建目录中使用正确的参数运行。那么这只是用简单的 make 构建的。

因此，想象中的目录结构可能如下所示。

/
|_/build-mylib-qt5-mingw32-debug
|_/build-mylib-qt5-mingw32-release
|_/build-mylib-qt4-msvc2010-debug
|_/build-mylib-qt4-msvc2010-release
|_/build-mylib-qt5-arm-debug
|_/build-mylib-qt5-arm-release
|_/mylib
  |_/include
  |_/src
  |_/resources

重要的是，qmake 在构建目录中运行：

cd build-mylib-XXXX
/path/to/right/qmake ../mylib/mylib.pro CONFIG+=buildtype ...

然后它会在 build 目录中生成 makefile，然后 make 也会在其下生成文件。只要 qmake 从未在源目录中运行（如果是，最好将其清理干净！），就没有不同版本混淆的风险。

像这样完成后，当前接受的答案中的 .pro 文件更加简单：

HEADERS += src/dialogs.h
SOURCES += src/main.cpp \
           src/dialogs.cpp

---

简短的回答是：你没有。

您应该在要构建的任何构建目录中运行 qmake，然后运行 make。因此，在 debug 目录中运行一次，在 release 目录中运行一次。

这就是构建您的项目的任何人都期望它工作的方式，这就是 Qt 本身设置构建的方式，这也是 Qt Creator 期望您的 .pro 文件的行为方式：它只是启动 qmake 然后 make 在为您的目标选择的配置构建文件夹。

如果您希望创建这些文件夹并在其中执行两个（或更多）构建，您将需要一个顶级 makefile，可能通过 qmake 从顶级项目文件创建。

拥有两个以上的构建配置并不少见，因此您不必要地承诺只区分构建和发布；您可能有不同优化级别的构建，等等。调试/发布二分法最好让其安息。

---

为输出可执行文件设置一个稍微不同的名称也很有用。你不能使用类似的东西：

release: Target = ProgramName
debug: Target = ProgramName_d

为什么它不起作用尚不清楚，但事实并非如此。但：

CONFIG(debug, debug|release) {
    TARGET = ProgramName
} else {
    TARGET = ProgramName_d
}

只要 CONFIG += 行在它之前，它就可以工作。

---

新版本的 Qt Creator 在调试和发布之间还有一个“配置文件”构建选项。这是我检测到的方式：

CONFIG(debug, debug|release) {  DEFINES += DEBUG_MODE }
else:CONFIG(force_debug_info) { DEFINES += PROFILE_MODE }
else {                          DEFINES += RELEASE_MODE }

---

这是我用于不同调试/发布输出目录的 Makefile。这个 Makefile 在 Ubuntu linux 上测试成功。如果正确安装了 Mingw-w64，它应该可以在 Windows 上无缝运行。

ifeq ($(OS),Windows_NT)
    ObjExt=obj
    mkdir_CMD=mkdir
    rm_CMD=rmdir /S /Q
else
    ObjExt=o
    mkdir_CMD=mkdir -p
    rm_CMD=rm -rf
endif

CC     =gcc
CFLAGS =-Wall -ansi
LD     =gcc

OutRootDir=.
DebugDir  =Debug
ReleaseDir=Release


INSTDIR =./bin
INCLUDE =.

SrcFiles=$(wildcard *.c)
EXEC_main=myapp

OBJ_C_Debug   =$(patsubst %.c,  $(OutRootDir)/$(DebugDir)/%.$(ObjExt),$(SrcFiles))
OBJ_C_Release =$(patsubst %.c,  $(OutRootDir)/$(ReleaseDir)/%.$(ObjExt),$(SrcFiles))

.PHONY: Release Debug cleanDebug cleanRelease clean

# Target specific variables
release: CFLAGS += -O -DNDEBUG
debug:   CFLAGS += -g

################################################
#Callable Targets
release: $(OutRootDir)/$(ReleaseDir)/$(EXEC_main)
debug:   $(OutRootDir)/$(DebugDir)/$(EXEC_main)

cleanDebug:
    -$(rm_CMD) "$(OutRootDir)/$(DebugDir)"
    @echo cleanDebug done

cleanRelease:
    -$(rm_CMD) "$(OutRootDir)/$(ReleaseDir)"
    @echo cleanRelease done

clean: cleanDebug cleanRelease
################################################

# Pattern Rules
# Multiple targets cannot be used with pattern rules [https://www.gnu.org/software/make/manual/html_node/Multiple-Targets.html]
$(OutRootDir)/$(ReleaseDir)/%.$(ObjExt): %.c | $(OutRootDir)/$(ReleaseDir)
    $(CC) -I$(INCLUDE) $(CFLAGS) -c $< -o"$@"

$(OutRootDir)/$(DebugDir)/%.$(ObjExt):   %.c | $(OutRootDir)/$(DebugDir)
    $(CC) -I$(INCLUDE) $(CFLAGS) -c $< -o"$@"

# Create output directory
$(OutRootDir)/$(ReleaseDir) $(OutRootDir)/$(DebugDir) $(INSTDIR):
    -$(mkdir_CMD) $@

# Create the executable
# Multiple targets [https://www.gnu.org/software/make/manual/html_node/Multiple-Targets.html]
$(OutRootDir)/$(ReleaseDir)/$(EXEC_main): $(OBJ_C_Release)
$(OutRootDir)/$(DebugDir)/$(EXEC_main):   $(OBJ_C_Debug)
$(OutRootDir)/$(ReleaseDir)/$(EXEC_main) $(OutRootDir)/$(DebugDir)/$(EXEC_main):
    $(LD) $^ -o$@

---

不确定是否有人会遇到像我这样的问题，但我会分享我的设置。我使用中央 proj.pri 文件来存储常规设置。我在每个子目录中都有 PKG.pro，它已经为调试模式设计。因此，当我尝试构建调试和发布时，我不想修改每个子目录中的每个 PKG.pro。我添加了相同的

DESTDIR = $${SOMEOTHERPATH}
release: DESTDIR = $${DESTDIR}/release
debug:   DESTDIR = $${DESTDIR}/debug

OBJECTS_DIR = $$DESTDIR/.obj
MOC_DIR = $$DESTDIR/.moc
RCC_DIR = $$DESTDIR/.qrc
UI_DIR = $$DESTDIR/.ui

这不起作用，因为在每个子目录中， DESTDIR 将再次被评估。它结束了双重调试或发布。为了避免这种情况，您必须只使用一个 DESTDIR 集，然后在每个子目录中，您可以包含这个 proj.pri 文件。这样，您无需编写一个 DIR 设置。并且需要“qmake CONFIG=debug”或“qmake CONFIG=release”来构建调试或发布。谁有更好的解决方案，请分享。

---