ChatGPT解决这个技术问题 Extra ChatGPT

How to delete files/subfolders in a specific directory at the command prompt in Windows

Say, there is a variable called %pathtofolder%, as it makes it clear it is a full path of a folder.

I want to delete every single file and subfolder in this directory, but not the directory itself.

But, there might be an error like 'this file/folder is already in use'... when that happens, it should just continue and skip that file/folder.

Is there some command for this?

It is insane how difficult Windows makes deleting folders... Or making one that starts with a dot... Thank god for Bash integration in Windows! rm -rf path\to\folder works in Windows 10 (or could come from Git Bash... either way if you have that it's wort a try!)

T
The Red Pea

rmdir is my all time favorite command for the job. It works for deleting huge files and folders with subfolders. A backup is not created, so make sure that you have copied your files safely before running this command.

RMDIR "FOLDERNAME" /S /Q

This silently removes the folder and all files and subfolders.


This seems to remove the pathtofolder the OP was wanting to keep.
This would remove the folder itself, so you'll need to add another command: md FOLDERNAME (see answer from @rakoczyn below).
What do you mean by "backup is created" here? I cannot see anything that would create any kind of backup...
The Directory is not empty Message came as response!
In order not to remove the folder itself, make it the current directory before, then use "." as FOLDERNAME. Re-creating it afterwards is not neccessarily the same because ACLs could be lost. cd "FOLDERNAME" RD . /S /Q
C
Community

You can use this shell script to clean up the folder and files within C:\Temp source:

del /q "C:\Temp\*"
FOR /D %%p IN ("C:\Temp\*.*") DO rmdir "%%p" /s /q

Create a batch file (say, delete.bat) containing the above command. Go to the location where the delete.bat file is located and then run the command: delete.bat


I tried it but unfortunately files where not deleted, only the sub-folders are deleted. For example I have a folder named Test. It contains 2 folders named as "Ripon" & "Wasim" and it contains a file named as "riponalwasim.txt". The subfolders Ripon and Wasim was deleted but riponalwasim.txt was not deleted.
Use single percentage sign if you wish to run direct from command line e.g. %p
Sad that this takes 2 lines, but at least it works! I'm tired of searching for a working "one-liner" and will go with this one, thanks!
You can use the '&&' operator to execute two commands in one line without a bat file (notice single '%' instead of '%%'). del /s /q "myfolder*" && FOR /D %p IN ("myfolder*") DO rmdir "%p" /s /q
The DEL command line misses option /A to delete also files with hidden attribute set and option /F to delete also files with read-only attribute set. So del /A /F /Q "C:\Temp\*" would be better. And FOR command line should be modified to for /F "eol=| delims=" %%I in ('dir "C:\Temp\*" /AD /B 2^>nul') do rd /Q /S "C:\Temp\%%I" because of FOR ignores directories with hidden attribute set. DIR with options /AD /B outputs all directories in C:\Temp with just their names.
S
Spontifixus

The simplest solution I can think of is removing the whole directory with

RD /S /Q folderPath

Then creating this directory again:

MD folderPath

what if you permission for deleting but not creating new folders?? I hope its possible :)
This is a bad solution, since it introduces a race on the file system for the directory node, i.e. the second command can fail if executed immediately after.
Also, bad solution if the directory has special permissions you just nuked ahem (whoops)
Don't be put off with the response: 'The directory is not empty.', just issue the command twice :-)
RD and RMDIR are the same command and since you posted this answer 9 months after someone stated the same answer, why are people giving you points?
f
foxidrive

This will remove the folders and files and leave the folder behind.

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)

For anyone not sure about this approach: it definitely does not re-create the directory. Without 2>nul, it outputs "The process cannot access the file because it is being used by another process."
I hate that Windows cannot delete files and folders being used by some program. And I love that you used that in your favor in this one-liner.
So this uber-magic is how we empty a folder in Windows?? Impressive :)
@mlvljr Only if you want to keep the parent folder too. RD /? will show you the simple way to empty a folder.
This is nice if you need to come back to your starting location, otherwise simply CD mypath && RD /S . would be enough. I don't like that you have to repeat your path twice though, for long paths it becomes hard to read. So I would just add a set p="mypath" at the beginning.
S
ScottN
@ECHO OFF

SET THEDIR=path-to-folder

Echo Deleting all files from %THEDIR%
DEL "%THEDIR%\*" /F /Q /A

Echo Deleting all folders from %THEDIR%
FOR /F "eol=| delims=" %%I in ('dir "%THEDIR%\*" /AD /B 2^>nul') do rd /Q /S "%THEDIR%\%%I"
@ECHO Folder deleted.

EXIT

...deletes all files and folders underneath the given directory, but not the directory itself.


this should be the right answer.. just make simple.. deletemyfoldercontents.bat file.. pop in your path and it works like a charm..
The DEL command line misses option /A to delete also files with hidden attribute set and %dir%\* should be enclosed in double quotes like "%dir%\*" to work also for directories containing a space or one of these characters &()[]{}^=;!'+,`~. And FOR command line should be modified to for /F "eol=| delims=" %%I in ('dir "%dir%\*" /AD /B 2^>nul') do rd /Q /S "%dir%\%%I" because of FOR ignores directories with hidden attribute set. DIR with options /AD /B outputs all directories with just their names. BTW: dir is not a good name for an environment variable.
does not delete sub folder
@RMiranda, in my tests, it does exactly as the OP asked. Do you have a case where it doesn't delete the subfolders?
Does this answer address the requirement "there might be an error like 'this file/folder is already in use'... when that happens, it should just continue and skip that file/folder."?
O
O.Badr
CD [Your_Folder]
RMDIR /S /Q .

You'll get an error message, tells you that the RMDIR command can't access the current folder, thus it can't delete it.

Update:

From this useful comment (thanks to Moritz Both), you may add && between, so RMDIR won't run if the CD command fails (e.g. mistyped directory name):

CD [Your_Folder] && RMDIR /S /Q .

From Windows Command-Line Reference:

/S: Deletes a directory tree (the specified directory and all its subdirectories, including all files). /Q: Specifies quiet mode. Does not prompt for confirmation when deleting a directory tree. (Note that /q works only if /s is specified.)


This is perfect for emptying temp, but that cd [Your_Folder] is super critical - I'll have to remember that so I don't delete the directory itself...
This is the correct solution. Add && between the commands instead of the line break and you are safe from a failing CD.
This is a simple et correct solution. Even works with Azure command shell!
pretty bad solution ... I for example need this command line deletion for a svn update - I want to delete all the files and folders before I make the update svn because there may be some changes on the machine where i use this, but relevant are only the checked in items. Doing RMDIR /S /Q . also removes the SVN link and therefore makes the folder no svn folder anymore
How is this different from the previous four answers?
r
rhellem

I use Powershell

Remove-Item c:\scripts\* -recurse

It will remove the contents of the folder, not the folder itself.


rhellem's answer is recent, but it is the only answer that will actually do this for me. (Win 8.1, not by choice)
From the batch command line: powershell -Command "Remove-Item 'PathToMyDirectory\*' -Recurse -Force"
Note that the "*" is necessary or it will remove the folder.
S
Sireesh Yarlagadda

RD stands for REMOVE Directory.

/S : Delete all files and subfolders in addition to the folder itself. Use this to remove an entire folder tree.

/Q : Quiet - do not display YN confirmation

Example :

RD /S /Q C:/folder_path/here

upvoted for being the only one to explain what /S and /Q mean
No.rd is equivalent to rmdir and will remove the directory itself and is not what OP wants.
Does this answer address the requirement "there might be an error like 'this file/folder is already in use'... when that happens, it should just continue and skip that file/folder."? For instance, does it abort completely instead of continuing?
P
Peter Mortensen

Use Notepad to create a text document and copy/paste this:

rmdir /s/q "%temp%"
mkdir "%temp%"

Select Save As and file name:

delete_temp.bat

Save as type: All files and click the Save button.

It works on any kind of account (administrator or a standard user). Just run it!

I use a temporary variable in this example, but you can use any other! PS: For Windows OS only!


a quite easy and clean solution
M
Mofi

None of the answers as posted on 2018-06-01, with the exception of the single command line posted by foxidrive, really deletes all files and all folders/directories in %PathToFolder%. That's the reason for posting one more answer with a very simple single command line to delete all files and subfolders of a folder as well as a batch file with a more complex solution explaining why all other answers as posted on 2018-06-01 using DEL and FOR with RD failed to clean up a folder completely.

The simple single command line solution which of course can be also used in a batch file:

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

This command line contains three commands executed one after the other.

The first command PUSHD pushes current directory path on stack and next makes %PathToFolder% the current directory for running command process.

This works also for UNC paths by default because of command extensions are enabled by default and in this case PUSHD creates a temporary drive letter that points to that specified network resource and then changes the current drive and directory, using the newly defined drive letter.

PUSHD outputs following error message to handle STDERR if the specified directory does not exist at all:

The system cannot find the path specified.

This error message is suppressed by redirecting it with 2>nul to device NUL.

The next command RD is executed only if changing current directory for current command process to specified directory was successful, i.e. the specified directory exists at all.

The command RD with the options /Q and /S removes a directory quietly with all subdirectories even if the specified directory contains files or folders with hidden attribute or with read-only attribute set. The system attribute does never prevent deletion of a file or folder.

Not deleted are:

Folders used as the current directory for any running process. The entire folder tree to such a folder cannot be deleted if a folder is used as the current directory for any running process. Files currently opened by any running process with file access permissions set on file open to prevent deletion of the file while opened by the running application/process. Such an opened file prevents also the deletion of entire folder tree to the opened file. Files/folders on which the current user has not the required (NTFS) permissions to delete the file/folder which prevents also the deletion of the folder tree to this file/folder.

The first reason for not deleting a folder is used by this command line to delete all files and subfolders of the specified folder, but not the folder itself. The folder is made temporarily the current directory for running command process which prevents the deletion of the folder itself. Of course this results in output of an error message by command RD:

The process cannot access the file because it is being used by another process.

File is the wrong term here as in reality the folder is being used by another process, the current command process which executed command RD. Well, in reality a folder is for the file system a special file with file attribute directory which explains this error message. But I don't want to go too deep into file system management.

This error message, like all other error messages, which could occur because of the three reasons written above, is suppressed by redirecting it with 2>nul from handle STDERR to device NUL.

The third command, POPD, is executed independently of the exit value of command RD.

POPD pops the directory path pushed by PUSHD from the stack and changes the current directory for running the command process to this directory, i.e. restores the initial current directory. POPD deletes the temporary drive letter created by PUSHD in case of a UNC folder path.

Note: POPD can silently fail to restore the initial current directory in case of the initial current directory was a subdirectory of the directory to clean which does not exist anymore. In this special case %PathToFolder% remains the current directory. So it is advisable to run the command line above not from a subdirectory of %PathToFolder%.

One more interesting fact: I tried the command line also using a UNC path by sharing local directory C:\Temp with share name Temp and using UNC path \\%COMPUTERNAME%\Temp\CleanTest assigned to environment variable PathToFolder on Windows 7. If the current directory on running the command line is a subdirectory of a shared local folder accessed using UNC path, i.e. C:\Temp\CleanTest\Subfolder1, Subfolder1 is deleted by RD, and next POPD fails silently in making C:\Temp\CleanTest\Subfolder1 again the current directory resulting in Z:\CleanTest remaining as the current directory for the running command process. So in this very, very special case the temporary drive letter remains until the current directory is changed for example with cd /D %SystemRoot% to a local directory really existing. Unfortunately POPD does not exit with a value greater 0 if it fails to restore the initial current directory making it impossible to detect this very special error condition using just the exit code of POPD. However, it can be supposed that nobody ever runs into this very special error case as UNC paths are usually not used for accessing local files and folders.

For understanding the used commands even better, open a command prompt window, execute there the following commands, and read the help displayed for each command very carefully.

pushd /?

popd /?

rd /?

Single line with multiple commands using Windows batch file explains the operators && and & used here.

Next let us look on the batch file solution using the command DEL to delete files in %PathToFolder% and FOR and RD to delete the subfolders in %PathToFolder%.

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Did the folder path consist only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Did the folder path consist only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

The batch file first makes sure that environment variable PathToFolder is really defined with a folder path without double quotes and without a backslash at the end. The backslash at the end would not be a problem, but double quotes in a folder path could be problematic because of the value of PathToFolder is concatenated with other strings during batch file execution.

Important are the two lines:

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

The command DEL is used to delete all files in the specified directory.

The option /A is necessary to process really all files including files with the hidden attribute which DEL would ignore without using option /A.

The option /F is necessary to force deletion of files with the read-only attribute set.

The option /Q is necessary to run a quiet deletion of multiple files without prompting the user if multiple files should be really deleted.

>nul is necessary to redirect the output of the file names written to handle STDOUT to device NUL of which can't be deleted because of a file is currently opened or user has no permission to delete the file.

2>nul is necessary to redirect the error message output for each file which can't be deleted from handle STDERR to device NUL.

The commands FOR and RD are used to remove all subdirectories in specified directory. But for /D is not used because of FOR is ignoring in this case subdirectories with the hidden attribute set. For that reason for /F is used to run the following command line in a separate command process started in the background with %ComSpec% /c:

dir "%PathToFolder%\*" /AD /B 2>nul

DIR outputs in bare format because of /B the directory entries with attribute D, i.e. the names of all subdirectories in specified directory independent on other attributes like the hidden attribute without a path. 2>nul is used to redirect the error message output by DIR on no directory found from handle STDERR to device NUL.

The redirection operator > must be escaped with the caret character, ^, on the FOR command line to be interpreted as a literal character when the Windows command interpreter processes this command line before executing the command FOR which executes the embedded dir command line in a separate command process started in the background.

FOR processes the captured output written to handle STDOUT of a started command process which are the names of the subdirectories without path and never enclosed in double quotes.

FOR with option /F ignores empty lines which don't occur here as DIR with option /B does not output empty lines.

FOR would also ignore lines starting with a semicolon which is the default end of line character. A directory name can start with a semicolon. For that reason eol=| is used to define the vertical bar character as the end-of-line character which no directory or file can have in its name.

FOR would split up the line into substrings using space and horizontal tab as delimiters and would assign only the first space/tab delimited string to specified loop variable I. This splitting behavior is not wanted here because of a directory name can contain one or more spaces. Therefore delims= is used to define an empty list of delimiters to disable the line splitting behavior and get assigned to the loop variable, I, always the complete directory name.

Command FOR runs the command RD for each directory name without a path which is the reason why on the RD command line the folder path must be specified once again which is concatenated with the subfolder name.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

del /?

dir /?

echo /?

endlocal /?

for /?

goto /?

if /?

rd /?

rem /?

set /?

setlocal /?


P
Peter Mortensen

You can do it by using the following command to delete all contents and the parent folder itself:

RMDIR [/S] [/Q] [drive:]path            

How is this different from the previous two answers?
Does this answer address the requirement "there might be an error like 'this file/folder is already in use'... when that happens, it should just continue and skip that file/folder."?
M
Maxim Suslov

To delete file:

del PATH_TO_FILE

To delete folder with all files in it:

rmdir /s /q PATH_TO_FOLDER

To delete all files from specific folder (not deleting folder itself) is a little bit complicated. del /s *.* cannot delete folders, but removes files from all subfolder. So two commands are needed:

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Yes this is correct. Must be two steps. This deserves more upvotes, because it explains why, in comparison with a more voted answer above.
The DEL command line misses option /A to delete also files with hidden attribute set and option /F to delete also files with read-only attribute set and double quotes around last argument. So del /A /F /Q "PATH_TO_FOLDER\*" would be better. And FOR command line should be modified to for /F "eol=| delims=" %%I in ('dir "PATH_TO_FOLDER\*" /AD /B 2^>nul') do rd /Q /S "PATH_TO_FOLDER\%%I" because of FOR ignores directories with hidden attribute set. DIR with options /AD /B outputs all directories in PATH_TO_FOLDER with just their names.
How is this different from (some of) the previous answers?
R
Robie Nayak
@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder's content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q

The 2nd line will remove the files in the each file from all the folders in Windows temp directory and the 3rd line cleans up the directories including its contents.
FOR command line should be modified to for /F "eol=| delims=" %%I in ('dir "%TEMP%\*" /AD /B 2^>nul') do rd /Q /S "%TEMP%\%%I" because of FOR ignores directories with hidden attribute set. DIR with options /AD /B outputs all directories in %TEMP% with just their names.
Documentation for DEL. I think you are on the right track with /F: "Ignore read-only setting and delete anyway (FORCE) "
P
Peter Mortensen

I tried several of these approaches, but none worked properly.

I found this two-step approach on the site Windows Command Line:

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

It worked exactly as I needed and as specified by the OP.


The two command lines can be combined to one command line: forfiles /P "%pathtofolder%" /M * /C "%SystemRoot%\System32\cmd.exe /C if @isdir==FALSE (del /A /F @file) else rd /Q /S @file" DEL option /A is added to delete also files with hidden attribute set as otherwise DEL would output a not found error message for each hidden file in %pathtofolder%. DEL option /F is added to delete also files with read-only attribute set in %pathtofolder% as otherwise DEL would output an access denied error message.
This solution is the slowest of all incomplete solutions posted here because of starting a cmd.exe instance for each file and each directory in %pathtofolder%. The advantage is that FORFILES does not ignore directories with hidden attribute set as FOR does.
Re "It worked exactly as I needed and as specified by the OP.": Did you test for the requirement "there might be an error like 'this file/folder is already in use'... when that happens, it should just continue and skip that file/folder."?
T
Tornike Shavishvili

I had following solution that worked for me:

for /R /D %A in (*node_modules*) do rmdir "%A" /S /Q

It removes all node modules folder from current directory and its sub-folders.

This is similar to solutions posted above, but i am still posting this here, just in case someone finds it useful


P
Peter Mortensen

Use:

del %pathtofolder%\*.*   /s /f  /q

This deletes all files and subfolders in %pathtofolder%, including read-only files, and does not prompt for confirmation.


Foe me this leaves empty subfolders in %pathtofolder%.
It does NOT delete subfolders in %pathtofolder%. So bad I have no reputation to vote down this false answer
As pointed out by Vitalii Korsakov, this deletes all files and files from subdirectories, but leaves the subdirectories in place which the OP asked how to remove as well.
Although this command does leave empty folders, it is much closer to what was requested, than the accepted answer. Ofcourse this depands on circumstances. In my case, I would rather have empty folders, than files left in root directory.
but how we can delete folders and sub-folder that were open in network share when other client machine open the share drive having write access to that folder.. psfile and net files command will close the file session but again after few seconds it will create automatically another session for that user in server...